If your program did the same thing regardless of how it was called, it wouldn’t be very useful. A real application responds to different situations by calling different code, which is the essence of flow control. In this article, you learn how to use conditional and loop logic to construct efficient flow control for your application. You also learn how to redirect the user to a different template and how to include code from external templates. An If construct consists of a condition and a dependent statement. ColdFusion evaluates the condition to determine whether it is True or False. If the condition is true, ColdFusion executes the dependent statement. Take, for example, the following code:

<cfif myVar GREATER THAN myOtherVar>
   <cfoutput>#myVar#</cfoutput>
   </cfif>

In the preceding If construct, ColdFusion tests to see whether myVar is greater than myOtherVar. If the test result is True, ColdFusion outputs the value of myVar; if the test result is False, ColdFusion doesn’t do anything. You can make ColdFusion execute alternative code if the condition tests False, as follows:

<cfif myVar GREATER THAN myOtherVar>
   <cfoutput>#myVar#</cfoutput>
   <cfelse>
   <cfoutput>#myOtherVar#</cfoutput>
   </cfif>

We’ve extended the original If construct to include a CFELSE tag. Now, if myVar is not greater than myOtherVar, ColdFusion outputs myOtherVar. You can extend CFIF even further by adding additional conditions with CFELSEIF, as follows:

<cfif myVar GREATER THAN myOtherVar>
   <cfoutput>#myVar#</cfoutput>
   <cfelseif myVar EQUAL myOtherVar>
   <cfoutput>#myVar + myOtherVar#</cfoutput>

<cfelse>
   <cfoutput>#myOtherVar#</cfoutput>
 </cfif>

Now, if myVar is equal to myOtherVar, ColdFusion adds the two together and outputs the result. Notice that the CFELSE statement now executes only if both the CFIF and CFELSEIF conditions are False. You can add as many CFELSEIF conditions as you want to a CFIF tag, but if you have more than two or three based on different results from the same conditional test, you should consider using a Switch construct instead. A Switch construct evaluates a single expression against multiple test values and then executes the block of code associated with the test value that matches. Consider the following snippet of code:

<cfif myVar EQ 1>
   One
 <cfelseif myVar EQ 2>
 Two
 <cfelseif myVar EQ 3>
 Three
 </cfif>

This snippet evaluates myVar three times, checking each time to determine whether myVar is a certain value. This code is better written by using a CFSWITCH block:

<cfswitch expression=”#myVar#”>
   <cfcase value=1>
   One
   </cfcase>
   <cfcase value=2>
   Two
   </cfcase>
   <cfcase value=3>
   Three
   </cfcase>
   </cfswitch>

Both snippets do the same thing, but the CFSWITCH construct is more efficient because it evaluates myVar once rather than three times. ColdFusion executes CFSWITCH statements more efficiently than it does CFIF statements, because CFIF evaluates each condition until it finds one that’s true, while CFSWITCH simply chooses the CFCASE block with the matching value. CFCASE values must be constant; in other words, the following construction is illegal:

<cfswitch expression=”#myVar#”>
   ...
 <cfcase value=”#1+1#”>
 Two
 </cfcase>
 ...
 </cfswitch>

This code would throw an error because variables and expressions are not permitted in CFCASE’s value attribute. In the code below, CFDEFAULTCASE is the Switch construct’s equivalent to CFELSE, as the following example shows:

<cfswitch expression=”#myVar#”>
   <cfcase value=1>
   One
   </cfcase>
   <cfcase value=2>
   Two
   </cfcase>
   <cfcase value=3>
   Three
   </cfcase>
   <cfdefaultcase>
   Some other number
   </cfdefaultcase>
   </cfswitch>

If none of the CFCASE values match the expression in CFSWITCH, ColdFusion executes the CFDEFAULTCASE block. Even with the benefits provided by CFSWITCH, at times you must still use CFIF logic. Take, for example, the following code block:

<cfif myVar GREATER THAN myOtherVar>
   <cfoutput>#myVar#</cfoutput>
   <cfelseif myVar EQUAL myOtherVar>
   <cfoutput>#myVar + myOtherVar#</cfoutput>
   <cfelse>
   <cfoutput>#myOtherVar#</cfoutput>
   </cfif>

This code cannot be converted to CFSWITCH because this CFIF construct contains multiple tests rather than a single test with a single expression. CFSWITCH uses its single expression as a “lookup key” to find the matching CFCASE to execute. The simplest type of loop loops from a specific starting point to a specific ending point—for example, from one to ten. This type of loop is called an index loop and is shown in the code.

This is code before the loop.<br>
   <cfloop from=”1” to=”10” index=”i”>
   <cfoutput>
   #i#<br>
   </cfoutput>
   </cfloop>
 This is code after the loop.<br>

Everything between <cfloop> and </cfloop> is the body of the loop. The body is executed once for each loop, and the loop index is incremented by 1 after each execution of the loop’s body. So what exactly does index=”i” mean? The index of a loop is a counter containing the number of the current loop iteration. In other words, for the first time through the loop, i would contain 1. The next time through, i would contain 2 and so on. After i reaches 10, the loop is executed one last time. This type of loop has one additional attribute. If we wanted to loop backwards from 10 to 1, we would include the step attribute, as in the code.

This is code before the loop.<br>
   <cfloop from=”10” to=”1” step=”-1” index=”i”>
   <cfoutput>
   #i#<br>
   </cfoutput>
   </cfloop>
 This is code after the loop.<br>

An index loop is appropriate if you know the number of loops in advance. You can, however, also loop an indefinite number of times while a given condition is true, as shown in the code.

<cfset bLoop = TRUE>
   <cfloop condition=”bLoop EQ TRUE”>
   This is one iteration through the loop.<br>
   <cfif RandRange(1, 10) EQ 10>
   <cfset bLoop = FALSE>
   </cfif>
 </cfloop>

RandRange(1,10) returns a random number between 1 and 10. The code keeps looping while bLoop is TRUE, and after RandRange() returns 10, we set bLoop to FALSE. If the loop attempts to execute again, the condition tests FALSE, and execution halts before the loops executes. CFLOOP can also loop over a query, as shown in the code. Remember that when looping over queries, you don’t surround the query object name with pound signs.

<cfquery name=”GetEmployees”
   datasource=”#Request.MainDSN#”>
   SELECT
   CompanyName
   FROM
   Company
   </cfquery>
   <cfoutput>
   <cfloop query=”GetEmployees”>
   #CompanyName#<br>
   </cfloop>
 </cfoutput>

The CFLOOP in the code loops over each row present in the GetEmployees query object and outputs each company name in the query. This type of loop is similar to a CFOUTPUT statement, except that CFLOOP can be nested inside of another CFOUTPUT (something that you cannot do with CFOUTPUT alone).